3.6. Wat is het gemiddeld bruto jaarsalaris per fte?

Concepten

• Arbeidsovereenkomst
• Contractomvang
• Contractomvangwaarde
• Grootboekpost
• Werkovereenkomst afspraak

Relaties

• deel van
• gaat over
• heeft deel
• heeft meeteenheid

Eigenschappen

• einddatum
• heeft datawaarde
• heeft datum
• heeftGeldBedrag
• startdatum

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: MEVA 3.6
2# Parameters: ?startperiode, ?eindperiode
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g: <http://purl.org/ozo/onz-g#>
6PREFIX onz-fin: <http://purl.org/ozo/onz-fin#>
7PREFIX onz-pers: <http://purl.org/ozo/onz-pers#>
8PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
9PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
10PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
11PREFIX time: <http://www.w3.org/2006/time#>
12
13
14SELECT 	
15	("Totaal organisatie" AS ?Indeling)
16    (?teller AS ?Totaal_bruto_jaarsalaris)
17	(?noemer AS ?Gewogen_fte)
18	(?teller / ?noemer AS ?Gemiddeld_bruto_jaarsalaris_per_fte)
19WHERE 
20{
21    {
22    SELECT ( SUM(?geld_bedrag) AS ?teller ) 
23    WHERE 
24    {
25        #BIND ("2024-01-01"^^xsd:date AS ?startperiode)
26        #BIND ("2024-12-31"^^xsd:date AS ?eindperiode)
27        VALUES ?rubriek { 
28            onz-fin:WPerSol
29            onz-fin:WPerLes
30            
31            onz-fin:411000
32            onz-fin:411100
33            onz-fin:411200
34            onz-fin:411300
35            onz-fin:411400
36            onz-fin:411500
37            onz-fin:411600
38            onz-fin:411700
39            onz-fin:412000
40            onz-fin:412100
41            onz-fin:412200
42            onz-fin:412300
43            onz-fin:412400
44            onz-fin:412500
45            onz-fin:413000
46            onz-fin:413100
47            onz-fin:413200
48            onz-fin:413300
49            onz-fin:413400
50            onz-fin:413500
51            onz-fin:413600
52            onz-fin:413610
53            onz-fin:413620
54            onz-fin:413700
55            onz-fin:414000
56            onz-fin:414100
57            onz-fin:414101
58            onz-fin:414102
59            onz-fin:414103
60            onz-fin:414104
61            onz-fin:414110
62            onz-fin:414111
63            onz-fin:414112
64            onz-fin:414113
65            onz-fin:414114
66            onz-fin:414200
67            onz-fin:414202
68            onz-fin:414203
69            onz-fin:414204
70            onz-fin:414300
71            onz-fin:414500
72            onz-fin:414503
73            onz-fin:414504
74            onz-fin:414700
75            onz-fin:414800
76            onz-fin:415000
77            onz-fin:422100
78            onz-fin:422300
79            onz-fin:422400
80            onz-fin:422410
81            onz-fin:422500
82            onz-fin:422600
83            onz-fin:422900
84            }
85            ?post onz-g:partOf ?rubriek .   
86
87        ?post a onz-fin:Grootboekpost ;
88            onz-g:hasDate ?datum ;
89            onz-fin:heeftGeldBedrag ?geld_bedrag .
90
91        FILTER (?datum >= ?startperiode && ?datum <= ?eindperiode)
92        }
93    }
94    {
95    SELECT (SUM(?subtotaal) as ?noemer)
96    WHERE 
97        {
98        SELECT (SUM(?omvang_factor_corr) as ?subtotaal)
99        WHERE
100        { 
101            # definieer periode waarin overeenkomst geldig moet zijn
102            #BIND ("2024-01-01"^^xsd:date AS ?startperiode)
103            #BIND ("2024-12-31"^^xsd:date AS ?eindperiode)
104
105            # Selecteer alle personeelsleden met een overeenkomst binnen de meetperiode
106            ?overeenkomst 
107                a onz-pers:ArbeidsOvereenkomst ;
108                onz-g:hasPart ?overeenkomst_afspraak . 
109            ?overeenkomst_afspraak
110                a onz-pers:WerkOvereenkomstAfspraak ;                     
111                onz-g:startDatum ?start_overeenkomst .
112            OPTIONAL {?overeenkomst_afspraak onz-g:eindDatum ?eind_overeenkomst }
113            FILTER (?start_overeenkomst <= ?eindperiode && (!BOUND(?eind_overeenkomst) || ?eind_overeenkomst >= ?startperiode))
114            ?overeenkomst_afspraak onz-g:hasPart ?omvang .  
115            ?omvang
116                a onz-pers:ContractOmvang ;
117                onz-g:isAbout ?omvang_waarde .
118            ?omvang_waarde
119                a onz-pers:ContractOmvangWaarde ;
120                onz-g:hasDataValue ?omvang_waarde_getal ;
121                onz-g:hasUnitOfMeasure ?omvang_waarde_eenheid .
122            ?omvang_waarde_eenheid onz-g:hasDataValue ?omvang_eenheid_factor .  
123            BIND(?omvang_waarde_getal/(36/?omvang_eenheid_factor) AS ?ptf)
124            
125            # corrigeer wanneer start of eind van de contractomvang buiten de gevraagde periode valt
126            BIND(IF(?startperiode > ?start_overeenkomst, ?startperiode, ?start_overeenkomst) AS ?start_overeenkomst_corr)
127            BIND(IF(?eindperiode < ?eind_overeenkomst || !BOUND(?eind_overeenkomst), ?eindperiode, ?eind_overeenkomst) AS ?eind_overeenkomst_corr)
128            
129            # bereken aantal dagen in de periode
130            ?startperiode ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?startperiode_reken .
131            ?eindperiode ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eindperiode_reken .
132            BIND(?eindperiode_reken - ?startperiode_reken + 1 AS ?dagen_periode)
133            
134            # bereken aantal dagen overeenkomst
135            ?start_overeenkomst_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?start_overeenkomst_reken .
136            ?eind_overeenkomst_corr ^time:inXSDDate/time:inTemporalPosition/time:numericPosition ?eind_overeenkomst_reken .
137            BIND(?eind_overeenkomst_reken - ?start_overeenkomst_reken + 1 AS ?dagen_overeenkomst)
138            
139            BIND (?dagen_overeenkomst/?dagen_periode AS ?factor)
140            
141            # Bereken relevant deel van de omvangwaarde
142            BIND (?factor * ?ptf AS ?omvang_factor_corr)
143        } 
144        GROUP BY ?overeenkomst_afspraak 
145        }
146	}
147}
148